Imports System.Reflection

Imports System.IO

Module Module1

    Private WithEvents appD As AppDomain = AppDomain.CurrentDomain

    Private Sub Display(ByVal s As String, ByVal left As Int32, ByVal color As ConsoleColor)

        Console.CursorLeft = left

        Console.ForegroundColor = color

        Console.WriteLine(s)

    End Sub

    Sub Main()

        Dim assemb As Assembly = Nothing

        Try

            ' Chargement de l'assembly en mode Reflection-Only

            assemb _

                = Assembly.ReflectionOnlyLoadFrom(Path.GetFileName(Assembly.GetExecutingAssembly().Location))

            ' Parcours des types

            For Each item As Type In assemb.GetTypes()

                Display(item.FullName, 0, ConsoleColor.DarkRed)

                ' Parcours des membres

                For Each m As MemberInfo In item.GetMembers()

                    Display(m.Name, 4, ConsoleColor.DarkGreen)

                Next

            Next

        Catch ex As ReflectionTypeLoadException

            Console.WriteLine(ex.ToString)

        Catch ex As Exception

            Console.WriteLine(ex.ToString)

        Finally

            Console.ReadLine()

        End Try

    End Sub

    Private Function appD_ReflectionOnlyAssemblyResolve(ByVal sender As Object, ByVal args As System.ResolveEventArgs) _

    As System.Reflection.Assembly Handles appD.ReflectionOnlyAssemblyResolve

        Return Assembly.ReflectionOnlyLoad(args.Name)

    End Function

End Module